47 lines
2.6 KiB
Julia
47 lines
2.6 KiB
Julia
using SpecialFunctions, WignerSymbols
|
|
include("common.jl")
|
|
|
|
# Gaussian potentials in HO space
|
|
inv_factorial(n) = Iterators.prod(inv.(1:n))
|
|
sqrt_factorial(n) = Iterators.prod(sqrt.(n:-1:1))
|
|
N_lnk(l, n, k) = 1/sqrt_factorial(n) * binomial(n, k) * sqrt(gamma(n + l + 3/2)) / gamma(k + l + 3/2)
|
|
Talmi(l, R, k1, k2; μω_gen=1.0) = (-1)^(k1 + k2) * (1 + 1/(μω_gen * R^2))^-(3/2 + l + k1 + k2) * gamma(3/2 + l + k1 + k2)
|
|
V_Gaussian(R, l, n1, n2; μω_gen=1.0) = (-1)^(n1 + n2) * better_sum([N_lnk(l, n1, k1) * N_lnk(l, n2, k2) * Talmi(l, R, k1, k2; μω_gen=μω_gen) for (k1, k2) in Iterators.product(0:n1, 0:n2)])
|
|
|
|
# for numerical evaluation of V matrix elements
|
|
sqrt_double_factorial(n) = Iterators.prod(sqrt.(n:-2:1))
|
|
sqrt_sqrt_pi = sqrt(sqrt(pi))
|
|
laguerre(l, n, x) = gamma(n + l + 3/2) * better_sum([(-x * x)^k / gamma(k + l + 3/2) * inv_factorial(n - k) * inv_factorial(k) for k in 0:n])
|
|
ho_basis_const(l, n) = (-1)^n / sqrt_sqrt_pi * (2.0)^((n + l + 2) / 2) * sqrt_factorial(n) / sqrt_double_factorial(2*n + 2*l + 1)
|
|
ho_basis_func(l, n, x) = x^(l + 1) * exp(-x^2 / 2) * laguerre(l, n, x)
|
|
ho_basis(l, n, x) = ho_basis_const(l, n) * ho_basis_func(l, n, x)
|
|
|
|
# for implementation of simple relative coordinates
|
|
double_factorial(n::Int) = Iterators.prod(big, n:-2:1)
|
|
|
|
"Gaussian integral for n ∈ Integers (Ref: Wolfram MathWorld + simplifications)"
|
|
gauss_int(a, n) = double_factorial(n - 1) / (2.0 * a)^((n + 1)/2) * (iseven(n) ? sqrt(π / 2) : 1)
|
|
|
|
"Gives ∫dp p u' u where u' and u are HO functions with different l (Ref: worked out in Mathematica)"
|
|
function integral_HO(np, lp, n, l, μω)
|
|
s = [(-1)^(m + mp) * gauss_int(1, 2 * m + 2 * mp + l + lp + 3) * N_lnk(l, n, m) * N_lnk(lp, np, mp) for (m, mp) in Iterators.product(0:n, 0:np)]
|
|
return 2 * sqrt(μω) * better_sum(s)
|
|
end
|
|
|
|
"Gives <n' l'|| p ||n l> for the HO basis, where integral(np, lp, n, l) is a function that returns ∫dp p u' u"
|
|
function reduced_matrix_element(np, lp, n, l, integral)::ComplexF64
|
|
wig::Float64 = wigner3j(Float64, lp, 1, l, 0, 0, 0)
|
|
if wig == 0
|
|
return 0
|
|
else
|
|
return (-1)^lp * sqrt(2*lp + 1) * sqrt(2*l + 1) * wig * integral(np, lp, n, l)
|
|
end
|
|
end
|
|
|
|
"Matrix element <n1p l1p n2p l2p| p1⋅p2 |n1 l1 n2 l2> (Ref: de-Shalit & Talmi, Eq 15.5), where integral(np, lp, n, l) is a function that returns ∫dp p u' u"
|
|
function racahs_reduction_formula(n1p, l1p, n2p, l2p, n1, l1, n2, l2, Λ, integral1, integral2)
|
|
val = wigner6j(Float64, l1p, l2p, Λ, l2, l1, 1)
|
|
if val != 0; val *= reduced_matrix_element(n1p, l1p, n1, l1, integral1); end
|
|
if val != 0; val *= reduced_matrix_element(n2p, l2p, n2, l2, integral2); end
|
|
return (-1)^(l1 + l2p + Λ) * val
|
|
end |