using Arpack, SparseArrays
include("ho_basis.jl")
include("p_space.jl")

Λ = 0
m = 1.0
Va = -2
Ra = 2

E_max = 40
μω_global = 0.5

# due to Jacobi coordinates
μ1ω1 = μω_global * 1/2
μ2ω2 = μω_global * 2
μ1 = m * 1/2
μ2 = m * 2/3

println("No of threads = ", Threads.nthreads())

@time "Basis" Es, n1s, l1s, n2s, l2s = get_2p_basis(E_max)
@time "Masks" begin
    mask1 = (n2s .== n2s') .&& (l2s .== l2s')
    mask2 = (n1s .== n1s') .&& (l1s .== l1s')
end

println("Basis size = ", length(Es))

println("Constructing KE matrices")
@time "T1" T1 = sp_T_matrix(n1s, l1s; mask=mask1, μω_gen=μ1ω1, μ=μ1)
@time "T2" T2 = sp_T_matrix(n2s, l2s; mask=mask2, μω_gen=μ2ω2, μ=μ2)

println("Constructing PE matrices")
V1_elem(l, n1, n2) = Va * V_Gaussian(Ra, l, n1, n2; μω_gen=μ1ω1)
V_relative_elem(l, n1, n2) = Va * V_Gaussian(Ra, l, n1, n2; μω_gen=μω_global)
@time "V1" V1 = sp_V_matrix(V1_elem, n1s, l1s; mask=mask1)
@time "V relative" V_relative = sp_V_matrix(V_relative_elem, n1s, l1s; mask=mask1) + sp_V_matrix(V_relative_elem, n2s, l2s; mask=mask2)
@time "Moshinsky brackets" U = Moshinsky_transform(Es, n1s, l1s, n2s, l2s, Λ)
@time "V2" V2 =  U' * V_relative * U

println("Calculating spectrum")
@time "H" H = T1 + T2 + V1 + V2
@time "Eigenvalues" evals, _ = eigs(H, nev=3, ncv=30, which=:SR, maxiter=5000, tol=1e-5, ritzvec=false, check=1)

display(evals)